0

Description

"Sometimes, one needs to recursively browse a directory and apply a processing on found files. The following snippet is in fact a single function that does exactly that.\r\nGiven a _path_ and a _callback_, it will recursively browse the file tree at _path_ and call the function _callback_ each time it encounters a file. The callback itself must have the following signature:\r\n`func f(s : String) -> void`.\r\nThe passed parameter is the absolute path of the file.\r\n\r\nThe function uses a stack and thus, does not perform recursive calls.\r\n\r\nHere is an example that prints the absolute path of all the files in a project:\r\n`recursive_processing(\"res:\/\/\", func f(s : String) -> void : print(\"File is %s\" % (s)))`"

Main code

func recursive_processing(path : String, callback : Callable) -> void:
	var dir : DirAccess = DirAccess.open(path)
	if dir:
		var stack : Array[DirAccess] = [ dir ]
		dir.list_dir_begin()
		while not stack.is_empty():
			var current : DirAccess = stack.back()
			var file_name : String = current.get_next()
			while not file_name.is_empty():
				var cur_dir_path : String = current.get_current_dir()
				var full_path : String = "%s%s%s" % [ cur_dir_path, "" if cur_dir_path.ends_with("/") else "/", file_name ]
				if current.current_is_dir():
					var d : DirAccess = DirAccess.open(full_path)
					if d:
						d.list_dir_begin()
						stack.push_back(d)
						break
				else:
					callback.call(full_path)
				file_name = current.get_next()
			if file_name.is_empty():
				stack.pop_back()

Comments