0

Description

"Remember the [Event Mapping contribution](https:\/\/thegodotbarn.com\/contributions\/snippet\/279\/mapping-physical-event-to-logical-event) ? A resource, `EventDescriptor` was described there. In order to ease in-game control remap, we need to be able to simply \"capture\" events and translate them into this kind of resource so they can be used in the mapper.\r\n\r\n> [!CAUTION]\r\n> After a successful capture, it is advised to disable the script by calling `set_process_input(false)`.\r\n\r\n> [!CAUTION]\r\n> The captured events are simplified as they are always \"toggle events\" (can be pressed and released).\r\n\r\n> [!CAUTION]\r\n> The captured keyboard events won't comprise modifiers. Instead, they're likely to be modifier keys themselves (like \"Shift\", \"Alt\", \"Ctrl\" and \"Meta\")\r\n\r\n## Signal\r\n\r\nThe signal `on_capture(descriptor : EventDescriptor)` is emitted upon a \"valid\" event capture.\r\n\r\n## Debugging\r\n\r\nA simple way to debug the produced event is to use the following functions.\r\n\r\n??? guide Output Example\r\n```gdscript\r\nconst JOY_BUTTONS_NAME : Dictionary[JoyButton, String] = {\r\n\tJOY_BUTTON_INVALID : \"Invalid\",\r\n\tJOY_BUTTON_A : \"A\",\r\n\tJOY_BUTTON_B : \"B\",\r\n\tJOY_BUTTON_BACK : \"BACK\",\r\n\tJOY_BUTTON_DPAD_DOWN : \"DPAD Down\",\r\n\tJOY_BUTTON_DPAD_LEFT : \"DPAD Left\",\r\n\tJOY_BUTTON_DPAD_RIGHT : \"DPAD Right\",\r\n\tJOY_BUTTON_DPAD_UP : \"DPAD Up\",\r\n\tJOY_BUTTON_GUIDE : \"Guide\",\r\n\tJOY_BUTTON_LEFT_SHOULDER : \"Left Shoulder\",\r\n\tJOY_BUTTON_LEFT_STICK : \"Left Stick Hat\",\r\n\tJOY_BUTTON_MISC1 : \"Miscellaeaous\",\r\n\tJOY_BUTTON_PADDLE1 : \"Paddle 1\",\r\n\tJOY_BUTTON_PADDLE2 : \"Paddle 2\",\r\n\tJOY_BUTTON_PADDLE3 : \"Paddle 3\",\r\n\tJOY_BUTTON_PADDLE4 : \"Paddle 4\",\r\n\tJOY_BUTTON_RIGHT_SHOULDER : \"Right Shoulder\",\r\n\tJOY_BUTTON_RIGHT_STICK : \"Right Stick Hat\",\r\n\tJOY_BUTTON_START : \"Start\",\r\n\tJOY_BUTTON_TOUCHPAD : \"Touchpad\",\r\n\tJOY_BUTTON_X : \"X\",\r\n\tJOY_BUTTON_Y : \"Y\"\r\n}\r\n\r\nconst JOY_AXISES_NAME : Dictionary[JoyAxis, String] = {\r\n\tJOY_AXIS_INVALID : \"Invalid\",\r\n\tJOY_AXIS_LEFT_X : \"Left X\",\r\n\tJOY_AXIS_LEFT_Y : \"Left Y\",\r\n\tJOY_AXIS_RIGHT_X : \"Right X\",\r\n\tJOY_AXIS_RIGHT_Y : \"Right Y\",\r\n\tJOY_AXIS_TRIGGER_LEFT : \"Left Trigger\",\r\n\tJOY_AXIS_TRIGGER_RIGHT : \"Right Trigger\"\r\n}\r\n\r\nconst MOUSE_BUTTONS_NAME : Dictionary[MouseButton, String] = {\r\n\tMOUSE_BUTTON_LEFT : \"Left\",\r\n\tMOUSE_BUTTON_MIDDLE : \"Middle\",\r\n\tMOUSE_BUTTON_RIGHT : \"Right\",\r\n\tMOUSE_BUTTON_WHEEL_DOWN : \"Wheel Down\",\r\n\tMOUSE_BUTTON_WHEEL_UP : \"Wheel Up\",\r\n\tMOUSE_BUTTON_WHEEL_LEFT : \"Wheel Left\",\r\n\tMOUSE_BUTTON_WHEEL_RIGHT : \"Wheel Right\",\r\n\tMOUSE_BUTTON_XBUTTON1 : \"Xtra 1\",\r\n\tMOUSE_BUTTON_XBUTTON2 : \"Xtra 2\"\r\n}\r\n\r\nfunc _print_captured_event(desc : EventDescriptor) -> void:\r\n\tprint_rich(\"Event Type : [b]%s[\/b]\" % (EventDescriptor.EventMedia.keys()[desc.kind]))\r\n\tmatch desc.kind:\r\n\t\tEventDescriptor.EventMedia.JOYSTICK:\r\n\t\t\tif desc.joy_button != JOY_AXIS_INVALID:\r\n\t\t\t\tprint_rich(\"Button [b]%s[\/b] [i]%s[\/i]\" % [ JOY_BUTTONS_NAME[desc.joy_button] if JOY_BUTTONS_NAME.has(desc.joy_button) else \"Unknown with code %d\" % (desc.joy_button), \"toggle\" if desc.toggle_event else (\"press\" if desc.is_pressed else \"release\") ])\r\n\t\t\telse:\r\n\t\t\t\tprint_rich(\"Axis [b]%s[\/b] [i]%s[\/i]\" % [ JOY_AXISES_NAME[desc.joy_axis] if JOY_AXISES_NAME.has(desc.joy_axis) else \"Unknown with code %d\" % (desc.joy_axis), \"toggle\" if desc.toggle_event else (\"press\" if desc.is_pressed else \"release\") ])\r\n\t\tEventDescriptor.EventMedia.MOUSE:\r\n\t\t\tprint_rich(\"Button [b]%s[\/b] [i]%s[\/i]\" % [ MOUSE_BUTTONS_NAME[desc.mouse_button] if MOUSE_BUTTONS_NAME.has(desc.mouse_button) else \"Unknown with code %d\" % (desc.joy_button), \"toggle\" if desc.toggle_event else (\"press\" if desc.is_pressed else \"release\") ])\r\n\t\tEventDescriptor.EventMedia.KEYBOARD:\r\n\t\t\tvar masks : Array[String] = []\r\n\t\t\tif desc.key_alt_modifier: masks.append(\"Alt\")\r\n\t\t\tif desc.key_ctrl_modifier: masks.append(\"Ctrl\")\r\n\t\t\tif desc.key_shift_modifier: masks.append(\"Shift\")\r\n\t\t\tif desc.key_meta_modifier: masks.append(\"Meta\")\r\n\t\t\tprint_rich(\"%s [b]%s[\/b] (%d)\" % [ \"\" if masks.is_empty() else \" - \".join(masks), OS.get_keycode_string(desc.key_code), desc.key_code ])\r\n```\r\n???\r\n"

Main code

extends Node

signal on_capture(descriptor : EventDescriptor)

func _capture_mouse_event(ev : InputEventMouseButton) -> EventDescriptor:
	if not ev.pressed:
		return null
	var desc : EventDescriptor = EventDescriptor.new()
	desc.kind = EventDescriptor.EventMedia.MOUSE
	desc.mouse_button = ev.button_index
	return desc

func _capture_joy_button_event(ev : InputEventJoypadButton) -> EventDescriptor:
	if not ev.pressed:
		return null
	var desc : EventDescriptor = EventDescriptor.new()
	desc.kind = EventDescriptor.EventMedia.JOYSTICK
	desc.joy_button = ev.button_index
	return desc

func _capture_joy_axis_event(ev : InputEventJoypadMotion) -> EventDescriptor:
	var desc : EventDescriptor = EventDescriptor.new()
	desc.kind = EventDescriptor.EventMedia.JOYSTICK
	desc.joy_axis = ev.axis
	return desc

func _capture_keyboard_event(ev : InputEventKey) -> EventDescriptor:
	if ev.echo or not ev.pressed:
		return null
	var desc : EventDescriptor = EventDescriptor.new()
	desc.kind = EventDescriptor.EventMedia.KEYBOARD
	desc.key_alt_modifier = ev.alt_pressed
	desc.key_ctrl_modifier = ev.ctrl_pressed
	desc.key_shift_modifier = ev.shift_pressed
	desc.key_meta_modifier = ev.meta_pressed
	desc.key_code = ev.keycode
	return desc

func _input(event : InputEvent) -> void:
	# Capture an event, and deactivate.
	var descriptor : EventDescriptor = null
	match event.get_class():
		"InputEventKey":
			descriptor = _capture_keyboard_event(event as InputEventKey)
		"InputEventMouseButton":
			descriptor = _capture_mouse_event(event as InputEventMouseButton)
		"InputEventJoypadButton":
			descriptor = _capture_joy_button_event(event as InputEventJoypadButton)
		"InputEventJoypadMotion":
			descriptor = _capture_joy_axis_event(event as InputEventJoypadMotion)
		_:
			pass
	if descriptor != null:
		on_capture.emit(descriptor)

Comments