0

Description

"## Introduction\r\n\r\n> [!NOTE]\r\n> tl;dr; The present script use the input events to generate simple signals when a game controller is used, with management of deadzone.\r\n\r\nYes, there's already a nice API in GDScript about managing inputs. But, sometimes, one wants things to be even simplier. The `Input` API is great, but it's an active process : One has to query status of particular device buttons or axises. Alas, it is not recommended to query inputs when they just don't occur, due to performance issue. That's why the `*_input` callbacks have to be used. And many of the work done in those callbacks are very common.\r\n\r\n**Hence this script**, performing the tasks of aggregating and filtering events and then notify via signals that something relevant happened, like a button\/trigger pressed or released. The sticks data are gathered (and filtered with deadzone management) at input events and can be retrieved with near to no overhead when one sees fit.\r\n\r\n## Parameters\r\n\r\n* **dead_zone** : The span of the dead_zone. A positive value set to *0.1* by default. The recommended values vary depending on the controller. One should rely on a calibration script to set it correctly (which will be the subject of a further article).\r\n* **device_filter** : An array of integer containing the controller identifiers to listen to. All others will be ignored. \r\n\r\n## Signals\r\n\r\n* **on_button_pressed** : `button_id : JoyButton, pressed : bool, controller_id : int` : Triggered when a button is pressed or released.\r\n* **on_trigger_pressed** : `axis_id : JoyAxis, pressed : bool, controller_id : int` : Triggered when the left or right trigger is pressed. It takes the deadzone into account.\r\n\r\n## Methods\r\n\r\n* **get_left_stick** : Returns the value of the (specified device) left stick.\r\n* **get_right_stick** : Returns the value of the (specified device) right stick.\r\n* **get_left_trigger** : Return the value of the (specified device) left trigger.\r\n* **get_right_trigger** : Return the value of the (specified device) right trigger.\r\n\r\n## Improvements\r\n\r\nIn order to not close any doors, I have left the possibility to filter devices and retrieve values for a specific device. But it could (should) have been more simple to just ignore this, especially if we are in a single player mode. In that case, the filtering part of the script could be removed and controller identifier ignored.\r\n\r\n```gdscript\r\nclass_name SinglePlayerPhysicalEventHandler\r\nextends Node\r\n\r\nsignal on_trigger_pressed(axis_id : JoyAxis, pressed : bool)\r\n\r\nsignal on_button_pressed(button_id : JoyButton, pressed : bool)\r\n\r\n@export var dead_zone : float = 0.1\r\n\r\n@onready var left_stick : Vector2 = Vector2.ZERO\r\n@onready var right_stick : Vector2 = Vector2.ZERO\r\n\r\n@onready var trigger_left_active : bool = false\r\n@onready var trigger_left : float = 0.\r\n\r\n@onready var trigger_right_active : bool = false\r\n@onready var trigger_right : float = 0.\r\n\r\nfunc _handle_motion(jev : InputEventJoypadMotion) -> void:\r\n\tvar value : float = 0. if abs(jev.axis_value) < dead_zone else jev.axis_value\r\n\tvar not_pressed : bool = is_zero_approx(value)\r\n\r\n\tmatch jev.axis:\r\n\t\tJOY_AXIS_LEFT_X:\r\n\t\t\tleft_stick.x = value\r\n\t\tJOY_AXIS_LEFT_Y:\r\n\t\t\tleft_stick.y = value\r\n\t\tJOY_AXIS_RIGHT_X:\r\n\t\t\tright_stick.x = value\r\n\t\tJOY_AXIS_RIGHT_Y:\r\n\t\t\tright_stick.y = value\r\n\t\tJOY_AXIS_TRIGGER_LEFT:\r\n\t\t\tif not_pressed == trigger_left_active:\r\n\t\t\t\ttrigger_left_active = !not_pressed\r\n\t\t\t\ton_trigger_pressed.emit(jev.axis, trigger_left_active)\r\n\t\t\ttrigger_left = value\r\n\t\tJOY_AXIS_TRIGGER_RIGHT:\r\n\t\t\tif not_pressed == trigger_right_active:\r\n\t\t\t\ttrigger_right_active = !not_pressed\r\n\t\t\t\ton_trigger_pressed.emit(jev.axis, trigger_right_active)\r\n\t\t\ttrigger_right = value\r\n\r\nfunc _handle_button(jev : InputEventJoypadButton) -> void:\r\n\ton_button_pressed.emit(jev.button_index, jev.pressed)\r\n\r\nfunc get_left_stick() -> Vector2:\r\n\treturn left_stick\r\n\r\nfunc get_right_stick() -> Vector2:\r\n\treturn right_stick\r\n\r\nfunc get_left_trigger() -> float:\r\n\treturn trigger_left\r\n\r\nfunc get_right_trigger() -> float:\r\n\treturn trigger_right\r\n\r\nfunc _input(event : InputEvent) -> void:\r\n\tif event is InputEventJoypadMotion:\r\n\t\t_handle_motion(event as InputEventJoypadMotion)\r\n\telif event is InputEventJoypadButton:\r\n\t\t_handle_button(event as InputEventJoypadButton\r\n```"

Main code

class_name PhysicalEventHandler
extends Node

signal on_trigger_pressed(axis_id : JoyAxis, pressed : bool, controller_id : int)

signal on_button_pressed(button_id : JoyButton, pressed : bool, controller_id : int)

@export var dead_zone : float = 0.1

@export var device_filter : Array[int] = [ 1 ] :
	set(value) :
		device_filter = value
		devices_state.clear()
		for i in value:
			if not devices_state.has(i):
				var state : GameControllerState = GameControllerState.new(i, dead_zone, on_trigger_pressed, on_button_pressed)
				devices_state[i] = state

class GameControllerState:
	var left_stick : Vector2 = Vector2.ZERO
	var right_stick : Vector2 = Vector2.ZERO

	var trigger_left_active : bool = false
	var trigger_left : float = 0.

	var trigger_right_active : bool = false
	var trigger_right : float = 0.

	var pad_id : int
	var dead_zone : float

	var axis_signal : Signal
	var button_signal : Signal

	func _init(id : int, d : float, a_s : Signal, b_s : Signal):
		pad_id = id
		dead_zone = d
		axis_signal = a_s
		button_signal = b_s

	func handle_motion(jev : InputEventJoypadMotion) -> void:
		var value : float = 0. if abs(jev.axis_value) < dead_zone else jev.axis_value
		var not_pressed : bool = is_zero_approx(value)

		match jev.axis:
			JOY_AXIS_LEFT_X:
				left_stick.x = value
			JOY_AXIS_LEFT_Y:
				left_stick.y = value
			JOY_AXIS_RIGHT_X:
				right_stick.x = value
			JOY_AXIS_RIGHT_Y:
				right_stick.y = value
			JOY_AXIS_TRIGGER_LEFT:
				if not_pressed == trigger_left_active:
					trigger_left_active = !not_pressed
					axis_signal.emit(jev.axis, trigger_left_active, jev.device)
				trigger_left = value
			JOY_AXIS_TRIGGER_RIGHT:
				if not_pressed == trigger_right_active:
					trigger_right_active = !not_pressed
					axis_signal.emit(jev.axis, trigger_right_active, jev.device)
				trigger_right = value

	func handle_button(jev : InputEventJoypadButton) -> void:
		button_signal.emit(jev.button_index, jev.pressed, jev.device)

	func get_left_stick() -> Vector2:
		return left_stick

	func get_right_stick() -> Vector2:
		return right_stick

	func get_left_trigger() -> float:
		return trigger_left

	func get_right_trigger() -> float:
		return trigger_right

@onready var devices_state : Dictionary[int, GameControllerState] = {}

func get_left_stick(device : int = 1) -> Vector2:
	return devices_state[device].get_left_stick() if devices_state.has(device) else Vector2.ZERO

func get_right_stick(device : int = 1) -> Vector2:
	return devices_state[device].get_right_stick() if devices_state.has(device) else Vector2.ZERO

func get_left_trigger(device : int = 1) -> float:
	return devices_state[device].get_left_trigger() if devices_state.has(device) else -1.

func get_right_trigger(device : int = 1) -> float:
	return devices_state[device].get_right_trigger() if devices_state.has(device) else -1.

func _input(event : InputEvent) -> void:
	if event is InputEventJoypadMotion:
		# Passive action => Update the stick and trigger state
		var jev : InputEventJoypadMotion = event as InputEventJoypadMotion
		if devices_state.has(jev.device):
			devices_state[jev.device].handle_motion(jev)
	elif event is InputEventJoypadButton:
		# Active action => Trigger action
		var jev : InputEventJoypadButton = event as InputEventJoypadButton
		if devices_state.has(jev.device):
			devices_state[jev.device].handle_button(jev)

Comments