0

Description

"This snippet is based on ['GDScript signals' by ava-cassiopeia](https:\/\/github.com\/ava-cassiopeia\/gdscript-signals) on the Asset Library.\r\n\r\n# Goal\r\n\r\n`Signals.first` `await`s multiple signals in parallel. When one of them is recieved, it stops waiting for the others and returns the signal that was recieved (and _not_ its data). This is intended for use with dialogs.\r\nIntuitively, to wait for confirmation, one would await the dialog's `confirmed` signal in their function. However, since the dialog might be canceled, the `confirmed` signal might never be emitted, leaving the function waiting forever, or being triggered at the wrong time if the dialog is opened again. The workaround would be to create a function and connect it to the `confirmed` signal, but this leads to code fragmentation across multiple functions, which harms readability.\r\n\r\n# Usage\r\n\r\n## Without `Signals.first`\r\n\r\n```gdscript\r\n@export var dialog: ConfirmationDialog\r\n\r\nfunc request_confirmation() -> void:\r\n dialog.confirmed.connect(_on_dialog_confirmed)\r\n dialog.show()\r\n\t\t\r\nfunc _on_dialog_confirmed() -> void:\r\n # Continue here\r\n pass\r\n```\r\n\r\n## With `Signals.first`\r\n\r\n### Using a `match` statement\r\n\r\n```gdscript\r\n@export var dialog: ConfirmationDialog\r\n\r\nfunc request_confirmation() -> void:\r\n dialog.show()\r\n match await Signals.first(dialog.canceled, dialog.confirmed):\r\n dialog.canceled:\r\n return\r\n dialog.confirmed:\r\n # Continue here\r\n pass\r\n # Or here\r\n pass\r\n```\r\n\r\n### Using an `if` statement\r\n\r\n```gdscript\r\n@export var dialog: ConfirmationDialog\r\n\r\nfunc request_confirmation() -> void:\r\n dialog.show()\r\n if await Signals.first(dialog.canceled, dialog.confirmed) == dialog.canceled:\r\n return\r\n # Continue here\r\n pass\r\n```"

Main code

@abstract
class_name Signals

## Adapted from https://github.com/ava-cassiopeia/gdscript-signals

static func first(...signal_list: Array) -> Signal:
    var listener := _AnySignalListener.new()
    for single_signal: Signal in signal_list:
        listener.add_signal(single_signal)
    var first_signal: Signal = await listener.any_signal_received
    return first_signal


class _AnySignalListener:
    signal any_signal_received(first_signal: Signal)
    var signal_list: Array[Signal] = []
    var completed: bool = false


    func add_signal(single_signal: Signal) -> void:
        assert(
            not completed,
            "Cannot add signal: this signal listener has already completed.",
        )
        signal_list.append(single_signal)
        # We use dummy arguments so the signal can connect successfully.
        single_signal.connect(func(_arg1 = null, _arg2 = null, _arg3 = null): _on_signal(single_signal))


    func _on_signal(sig: Signal) -> void:
        if completed:
            return
        any_signal_received.emit(sig)
        _disconnect_all_signals()
        completed = true


    func _disconnect_all_signals() -> void:
        if completed:
            return
        for single_signal in signal_list:
            if not single_signal.get_object():
                continue
            if single_signal.is_connected(_on_signal):
                single_signal.disconnect(_on_signal)

Comments