1

Description

"there is an extraneous signal in here to send signals for like, a text notification or whatever but the logic goes like this - if you took a screenshot, it checks if you are in the editor (it will make a folder in your projectfolder) or if you're using the exported compiled exe (it makes a folder where your exe is.) it then uses a separate thread to take your screenshot and give it a name.\nit saves it as a png\nit makes it so there is no hitching when you take a screenshot at all even though its saving like a 4 mb png\n`WorkerThreadPool` is how you do this\n\nScreenshot names come out like\n```\nScreenshot_2024-11-15_23-40-10.png\n```\nand they're in a folder named 'screenshots' that is created in the same folder as the project, or the exe\nyou can reformat that how you like"

Main code

extends Node

signal save_finished()
signal screenshot_captured()
# keep track of tasks in a property, because we cannot read task_id from the lambda before add_task has finished
var tasks: Array[int] = []

func _ready() -> void:
    process_mode = Node.PROCESS_MODE_ALWAYS

func _init() -> void:
    save_finished.connect(func() -> void:
        # take the oldest finished task
        var task_id: int = tasks.pop_front()
        WorkerThreadPool.wait_for_task_completion(task_id)
    )

func take_screenshot(path: String) -> void:
    if !DirAccess.dir_exists_absolute(path + "screenshots"):
        var dir: DirAccess = DirAccess.open(path); dir.make_dir("screenshots")
    var screenshots_folder: String = path + "screenshots"
    await RenderingServer.frame_post_draw
    var screenshot: Image = get_viewport().get_texture().get_image()
    screenshot_captured.emit.call_deferred()
    var task_id: int = WorkerThreadPool.add_task(func() -> void:
        var datetime: Dictionary = Time.get_datetime_dict_from_system()
        var imgPath: String = screenshots_folder.path_join("Screenshot_%04d-%02d-%02d_%02d-%02d-%02d.png" % [datetime.year,datetime.month,datetime.day,datetime.hour,datetime.minute,datetime.second])
        screenshot.save_png(imgPath)
        # notify task completion with call_deferred to clean it up on the main thread
        save_finished.emit.call_deferred()
    )
    tasks.append(task_id)

func _physics_process(_delta: float) -> void:
    if Input.is_action_just_pressed("screenshot"):
        if Engine.is_editor_hint() || OS.has_feature("editor"):
            take_screenshot("res://")
        else:
            take_screenshot(OS.get_executable_path().get_base_dir())

Comments