0

Description

"According to a Steam survey, 50% of the players have at least 2 monitors. One nice-to-have accessibility feature should be to select on which monitor you want to display your application (fullscreen or not).\r\n\r\nThe following snippet is a custom UI that displays the current layout of the monitors along with their identifier (screen number). It is NOT meant to manage screen selection, only display.\r\n\r\nIf you have a control that allows selecting a screen, just change the value of the parameter `selected_screen` to highlight the select screen.\r\n\r\n# How to use\r\n\r\nJust attach the following script to any node that inherit `Control`. It will draw the layout inside the UI node area.\r\n\r\n# Function\r\n\r\n* `int get_screen(pos : Vector2, select : bool = false)` : Provide the screen at the position `pos` (local to the node). If `select` is set to _true_, the screen will be selected in the UI as well.\r\n\r\n??? guide Basic Example of Screen Selection by Mouse\r\nCreate a new `Node` and attach the following script:\r\n```gdscript\r\nextends Node\r\n\r\n@export var screen_mapping : Control\r\n\r\nfunc _input(event : InputEvent) -> void:\r\n\tvar click: InputEventMouseButton = event as InputEventMouseButton\r\n\tif not click:\r\n\t\treturn\r\n\r\n\tif click.pressed and click.button_index == MOUSE_BUTTON_LEFT and not click.is_echo():\r\n\t\tclick = screen_mapping.make_input_local(click)\r\n\t\tvar selected: int = screen_mapping.get_screen(click.position, true)\r\n\t\tprint(\"Selected screen %d\" % (selected))\r\n```\r\n\r\nAdd the monitor display node in the `screen_mapping` parameter and there you go.\r\nWhen clicking on the screens, it will select the one under the cursor and print the ID on the standard output (console).\r\n\r\n\r\n???\r\n\r\n# Parameters\r\n\r\n* **selected_screen** : Selected screen ID. Allows highlighting one screen given its identifier.\r\n* **color_selected** : Foreground\/Border color of the selected screen.\r\n* **color_background_selected** : Background color of the selected screen.\r\n* **color_not_selected** : Default screen foreground\/border color.\r\n* **color_background_not_selected** : Default screen background color.\r\n* **border_size_selected** : Border size of the selected screen (in pixels).\r\n* **border_size_not_selected** : Default screen border size (in pixels).\r\n* **font** : Font used for identifier display. It is optional. If not present, the ID won't be displayed.\r\n* **font_size** : Font size.\r\n* **font_margin** : Text margin (in pixels).\r\n\r\nIf a font is specified, the ID of the screen will be displayed on the lower left of the screen rectangle, with the color associated to the selection."

Screenshots

Main code

extends Control

@export var selected_screen : int = -1 :
	set(value):
		selected_screen = value
		queue_redraw()

@export_subgroup("Colors", "color_")
@export var color_selected : Color = Color.WHITE
@export var color_background_selected : Color = Color(1., 1., 1., 0.8)
@export var color_not_selected : Color = Color.DARK_GRAY
@export var color_background_not_selected : Color = Color(0.2, 0.2, 0.2, 0.8)

@export_subgroup("Border", "border_")
@export var border_size_selected : float = 2.
@export var border_size_not_selected : float = 1.

@export_subgroup("Text", "font_")
@export var font : Font
@export var font_size : int = 16
@export var font_margin : Vector2 = Vector2(2., 2.)

@onready var screens : Array[Rect2] = []

func _ready() -> void:
	queue_redraw()

func _get_screen_rect(id : int) -> Rect2:
	return Rect2(DisplayServer.screen_get_position(id), DisplayServer.screen_get_size(id))

func _draw() -> void:
	screens.clear()
	var count : int = DisplayServer.get_screen_count()

	var screen_size : Rect2 = _get_screen_rect(0)
	screens.append(screen_size)
	var screen_accumulation : Rect2 = screen_size

	for i : int in range(1, count):
		screen_size = _get_screen_rect(i)
		screens.append(screen_size)
		screen_accumulation = screen_accumulation.merge(screen_size)

	var overall_size : Vector2i = screen_accumulation.size
	var ratio : Vector2 =  size / Vector2(overall_size)
	var draw_ratio : float = min(ratio.x, ratio.y)
	var offset : Vector2 = screen_accumulation.position

	for i : int in range(count):
		var s : Rect2 = screens[i]
		s.position -= offset
		s.position *= draw_ratio
		s.size *= draw_ratio
		screens[i] = s

	for i : int in range(count):
		if i != selected_screen:
			var s : Rect2 = screens[i]
			_draw_screen_hint(s, color_not_selected, color_background_not_selected, border_size_not_selected, i)

	if selected_screen in range(count):
		_draw_screen_hint(screens[selected_screen], color_selected, color_background_selected, border_size_selected, selected_screen)

func _draw_screen_hint(rect : Rect2, color : Color, background : Color, thickness : float, id : int) -> void:
	draw_rect(rect, background, true)
	draw_rect(rect, color, false, thickness, true)
	if font != null:
		draw_string(font, rect.position + Vector2(font_margin.x, rect.size.y - font_margin.y), str(id), HORIZONTAL_ALIGNMENT_LEFT, -1, font_size, color)

func get_screen(pos : Vector2, select : bool = false) -> int:
	var selected : int = -1
	for i : int in range(screens.size()):
		var s : Rect2 = screens[i]
		if s.has_point(pos):
			selected = i
			break
	if select:
		selected_screen = selected
	return selected

Comments