Description

Have you ever created a new exported variable, like that:

gdscript@export var audio_player: AudioStreamPlayer

Then wrote a function that gets called very late into the game, like that:

gdscriptfunc _on_player_won() -> void:
	audio_player.play()

Just to see an error message, like that:

Cannot call method 'play' on a null value.

Because you forgot to assign the reference to your exported variable?

Fear not, because this snippet saves you from all of that hassle. Just put this into the ready() function of your Node

gdscriptfunc _ready() -> void:
	Debugger.assert_all_exported_properties(self)

And if you forgot to assign the reference to any of your exported variables on that Node, it will trigger an error right when the _ready() is called, not when the faulty variable is called. It will point to the missing property and location of the source Node in the SceneTree.

Assertion failed: -"audio_player"- property on node: -"/root/GameManager"- is missing assignment

It uses @GlobalScope PropertyUsageFlags to evaluate which properties to assert. Combination of PROPERTY_USAGE_SCRIPT_VARIABLE | PROPERTY_USAGE_EDITOR | PROPERTY_USAGE_STORAGE flags is an exported variable.

Here's some more example usage:

gdscript## some_class.gd
class_name SomeClass

@export var exported_property_node: Node
@export var exported_property_packed_scene: PackedScene
@export var exported_property_bool: bool
var not_exported_property_node: Node
var not_exported_property_packed_scene: PackedScene
var not_exported_property_bool: bool

func _ready() -> void:
	Debugger.assert_all_exported_properties(self)

This call will check the 3 exported properties of type: Node, PackedScene and bool. If the Node or PackedScene properties have not been assigned in the editor, it will run into an error and pause the editor. bool is always assigned either true or false, so it won't raise an error.

It's not perfect, but is very easy and should be plug-and-play for most projects. It has saved me already so many hours during testing, I hope it will serve you just as well!

Main code

## debugger.gd
class_name Debugger

## This function checks all exported properties of a Node to see if there are any unassigned in the editor.
## If there are unassigned properties, it will run into an error and pause the editor.
static func assert_all_exported_properties(node: Node) -> void:
	var script: Script = node.get_script()
	var property_list: Array[Dictionary] = script.get_script_property_list()
	for property: Dictionary in property_list:
		if property.usage == PROPERTY_USAGE_SCRIPT_VARIABLE | PROPERTY_USAGE_EDITOR | PROPERTY_USAGE_STORAGE:
			var error_message: String = "-\"%s\"- property on node: -\"%s\"- is missing assignment"
			var property_name: String = property.name
			var property_value: Variant = node.get(property_name)
			assert(property_value != null, error_message % [property.name, str(node.get_path())])

Comments