Get children Nodes of specific Type

Description

"These methods are fully type-safe, work with all types, including custom types, and require no String comparisons.\r\nIt will hopefully become obsolete when [Traits are introduced into GDScript](https:\/\/github.com\/godotengine\/godot-proposals\/issues\/6416), but until then it is a pretty good alternative filling the gap for a type-safe Component pattern.\r\n\r\nHere's some example usage for `Interactable` nodes.\r\n```\r\n## Player.gd\r\nclass_name Player\r\nfunc _ready() -> void:\r\n\tvar typed_children: Array[Interactable]\r\n\ttyped_children.assign(UtilityClass.get_children_of_type(self, Interactable)) # Returned array from function is not typed, so we have to assign it to a typed array\r\n\tfor child: Interactable in typed_children:\r\n\t\tchild.interact()\r\n  \r\n\tvar first_child_of_type: Interactable = UtilityClass.get_child_of_type(self, Interactable) as Interactable # Returned Node from function is not typed, so we have to cast it to a Type\r\n\tif first_child_of_type != null:\r\n\t\tfirst_child_of_type.interact()\r\n\r\n\r\n## Interactable.gd\r\nclass_name Interactable\r\nfunc interact() -> void:\r\n\t# do some interaction\r\n\tpass\r\n```"

Main code

## utility_class.gd
class_name UtilityClass


## Returns all children of given type.
## The returned Array is untyped, so it has to be assigned to a typed array later.
static func get_children_of_type(parent: Node, type: Variant) -> Array:
	var array: Array
	for child: Node in parent.get_children():
		if is_instance_of(child, type):
			array.append(child)
	return array 


## Returns the first child of given type, will ignore the other children.
## The returned Node is untyped, so it has to be casted to a type later.
static func get_child_of_type(parent: Node, type: Variant) -> Node:
	if parent == null:
		return null
	for child: Node in parent.get_children():
		if is_instance_of(child, type):
			return child
	return null

Description

Main code

Comments

Table of contents

Compatibility

Tags